函数：DCONCAT

功能：连接指定的一组记录（域）中的一组值的字符串。

语法：DCONCAT(expr, domain, [criteria],[delimiter])

示例：
NewOrder

查询：
SELECT DISTINCT DCONCAT("DISTINCT Name","NewOrder","","/") As Name FROM NewOrder

查询：
SELECT DISTINCT OrderID ,DCONCAT("Name","NewOrder","OrderID='" & OrderID & "'") As Name FROM NewOrder

OrderID	Name
001021	五子棋,象棋,跳棋
001022	跳棋,象棋
001023	五子棋,跳棋

函数实现：

Public Function DCONCAT(sExpr As String, sDomain As String, Optional sCriteria As String, Optional sDelimiter As String = ",")
    On Error GoTo ErrHandler
   
    Dim rs As New ADODB.Recordset
   
    Dim sSQL As String
    Dim sResult As String
    sResult = ""
   
    sSQL = "select " & sExpr & " from (" & sDomain & ")"
    If sCriteria <> "" Then
        sSQL = sSQL & " where " & sCriteria
    End If
   
    rs.Open sSQL, CurrentProject.Connection, adOpenForwardOnly, adLockReadOnly
   
    Do While Not rs.EOF
        If sResult <> "" Then
            sResult = sResult & sDelimiter
        End If
        sResult = sResult & rs.Fields(0).Value
        rs.MoveNext
    Loop
   
    rs.Close
    Set rs = Nothing
   
    DCONCAT = sResult
   
    Exit Function
   
ErrHandler:
    If rs.State <> adStateClosed Then
        rs.Close
    End If
    Set rs = Nothing
   
    DCONCAT = Err.Number & " : " & Err.Description
End Function